@verb #4214:"@paste*-to" any any any rxo #8438
@program #4214:"@paste*-to" any any any
"Syntax: @paste"
"	@paste <player> [<player>..]"
"If no players are specified, the text will be announced to all players in the room."
this:update_usage("paste", player)
header = $string_utils:center(tostr($string_utils:nn(player) + " @pastes:"), player:linelength(), "-")
footer = $string_utils:center(tostr("End of @paste"), player:linelength(), "-")
if (dobj == $nothing)
  who = $set_utils:intersection(player.location.contents, connected_players())
else
  targets = $string_utils:words(argstr)
  who = {}
  for n in (targets)
    $command_utils:suspend_if_needed(1)
    person = $string_utils:match_player(n)
    if (n != $failed_match && n != $ambiguous_match)
      who = {@who, person}
    else
      player:tell("`", n, "' was not found.")
    endif
  endfor
endif
who = setadd(who, player)
player:tell("Now @pasting to: ", $string_utils:name_and_number_list(who), ".")
pastetext = $command_utils:read_lines()
final = {header}
for n in (pastetext)
  $command_utils:suspend_if_needed(1)
  if (length(n) > 0)
    final = {@final, n}
  endif
endfor
final = {@final, footer}
for x in (who)
  suspend(0)
  x:tell(final)
endfor
.