@verb #4000:"grep*" any any any rdo #4000
@program #4000:"grep*" any any any
player == this || one == two
argstr = $html_utils:de_literal_text(argstr)
verb = verb[5..$]
f_regex = index(verb, "r")
f_wiz = index(verb, "w")
f_debug = index(verb, "d")
f_exec = index(verb, "x")
f_override = index(verb, "o")
f_fertile = index(verb, "f")
f_tnt = index(verb, "t")
i = 0
for o in [#0..max_object()]
  $cmd_utils:suspend_if_needed()
  if (f_fertile && !o.f)
    continue
  endif
  verbs = `verbs(o) ! E_PERM => {}'
  for v in [1..length(verbs)]
    $cmd_utils:suspend_if_needed()
    try
      info = verb_info(o, v)
      if (f_wiz && !info[1].wizard)
        continue
      endif
      if (f_debug && index(info[2], "d"))
        continue
      endif
      if (f_exec && !index(info[2], "x"))
        continue
      endif
      if (f_override && !index(info[2], "o"))
        continue
      endif
      if (f_tnt && verb_args(o, v) != {"this", "none", "this"})
        continue
      endif
      if (argstr)
        code = verb_code(o, v, 1, 0)
        for l in [1..length(code)]
          if (f_regex ? match(code[l], argstr) | index(code[l], argstr))
            junk = tostr(o, ":\"", verbs[v], "\"(", v, ") [", l, "]")
            if (length(junk) <= 35)
              player:notify($html_utils:literal_text(junk + $su:space(36 - length(junk)) + code[l]))
            else
              player:notify($html_utils:literal_text({junk, "                                    " + code[l]}))
            endif
            i = i + 1
            if (i % 100 == 0 && !$cmd_utils:yn("Continue?"))
              break o
            endif
          endif
        endfor
      else
        player:notify($html_utils:literal_text(tostr(o, ":\"", verbs[v], "\"(", v, ")")))
        i = i + 1
        if (i % 100 == 0 && !$cmd_utils:yn("Continue?"))
          break o
        endif
      endif
    except (E_PERM)
    endtry
  endfor
endfor
player:notify(tostr("Done; total ", i, " found."))
.