@verb #3936:"@verbs*" any none none rdo #3936
@program #3936:"@verbs*" any none none
blank = "?  ?  ?"
set_task_perms(player)
if (!dobjstr)
  try
    if (verb[7] != "(" && verb[$] != ")")
      player:tell("Usage:  @verbs <object>")
      return
    else
      dobjstr = verb[8..$ - 1]
    endif
  except (E_RANGE)
    return player:tell("Usage:  @verbs <object>")
  endtry
endif
thing = player:my_match_object(dobjstr)
if (!$command_utils:object_match_failed(thing, dobjstr))
  verbs = $caselib:accessible_verbs(thing)
  player:tell()
  player:tell("", tostr(length(verbs)), " verbs found on ", thing:title(), " (", thing, ").")
  player:tell("+----------------------+-------+-----------------+-----------+")
  player:tell("| Verb Name            | Perms | Verb Owner      | Arguments |")
  player:tell("+-", $string_utils:space(20, "-"), "-+-------+-", $string_utils:space(15, "-"), "-+-", $string_utils:space(10, "-"), "+", $string_utils:space(player:linelen() - 64, "-"), "+")
  for vrb in (verbs)
    if (vrb == E_PERM)
      name = blank
      allargs = blank
      owner = blank
      perms = "???"
    else
      name = vrb
      arg_specs = verb_args(thing, vrb)
      {owner, perms, names} = verb_info(thing, vrb)
      allargs = arg_specs[1] + " " + arg_specs[2] + " " + arg_specs[3]
      if (valid(owner))
        owner = owner.name + " (" + tostr(owner) + ")"
      else
        owner = "*** NONE ***"
      endif
    endif
    player:tell("| " + $who_utils:convsize(name, 20) + " | ", $who_utils:convsize(perms, 5), " | ", $who_utils:convsize(owner, 15), " | ", $who_utils:convsize(allargs, player:linelen() - 53), "|")
    $command_utils:suspend_if_needed(1)
  endfor
  if (!verbs)
    player:tell("| ", $string_utils:space(20, " "), " | ", $string_utils:space(5, " "), " | ", $string_utils:space(15, " "), " | ", $string_utils:space(player:linelen() - 53, " "), "|")
  endif
  player:tell("+-", $string_utils:space(20, "-"), "-+-------+-", $string_utils:space(15, "-"), "-+-", $string_utils:space(player:linelen() - 53, "-"), "+")
  player:tell("", tostr(length(verbs)), " verbs found on ", thing:title(), " (", thing, ").")
  player:tell()
endif
"Last modified by Vladmir (#3936) on Fri Dec 31 11:12:46 2004 MST."
.