@verb #3817:"tell_exits" this none this rxdo #9921
@program #3817:"tell_exits" this none this
exits = args[1]
text = {}
apts = {}
if (player:display_pueblo() && player.location == this)
  return this:do_pueblo_exits(exits)
endif
for x in (exits)
  name = `x.name ! E_TYPE => x->aliases[1]'
  if (`listiassoc($get_property(x, "dest"), $MCA.rooms, 3) ! ANY => 0')
    apts = {@apts, x}
  elseif (name in {"out", "up", "down"})
    text = {@text, `$get_property(x, "exit_desc") ! ANY => tostr($string_utils:capitalize($call_verb(x, "title", {})), " leads to ", $get_property(x, "dest"):title(), ".")'}
  elseif (name == "elevator")
    text = {@text, tostr(" The Elevator doors are open.")}
  else
    text = {@text, `$get_property(x, "exit_desc") ! ANY => tostr("To the ", $calL_verb(x, "title", {}), " you see ", $get_property(x, "dest"):title(), ".")'}
  endif
  $command_utils:suspend_if_needed()
endfor
if (apts)
  text = {@text, tostr($string_utils:title_list(apts), " lead", (a = length(apts) > 1) ? "" | "s", " to the according apartment", a ? "s" | "", ".")}
endif
player:tell(text)
"Last modified by Lao-Tzu (#8084) on Mon Aug 12 08:41:19 2002 MDT."
.