@verb #3512:"spy_times" this none this rxdo #6319
@program #3512:"spy_times" this none this
caller != this && raise(E_PERM)
"Just a small security leak...oops."
rp = prepstr ? player.user | player
t = dobj.first_connect_time
this:tellit(player, "%d first connected on %1", t == $maxint ? "[No connections]" | ctime(t))
if (t != $maxint)
  if ((w = #2774:player_age(dobj)) == E_QUOTA)
    this:tellit(player, "%d doesn't want anyone to know %d~p MOO-age.")
  else
    suspend(0)
    this:tellit(player, "%d is %1 old.", $time_utils:english_time(w))
  endif
  if (r = `#2774:determine_age(rb = dobj.real_bday) ! ANY => 0')
    this:tellit(player, "Real Birthday: %1", ctime(rb))
    $command_utils:suspend_if_advisable()
    this:tellit(player, "Real age: %1", $time_utils:english_time(r))
  endif
endif
"The only dog in the world that thinks there should be more ticks."
suspend(0)
if (dobj:connected(rp:isa($guardian)))
  this:tellit(player, "Connected: %1", $time_utils:english_time(dobj:connected_seconds()))
  this:tellit(player, "Idle: %1", $time_utils:english_time(dobj:idle_seconds()))
else
  t != $maxint && this:tellit(player, ": %1", ctime(dobj.last_disconnect_time))
endif
"Last modified by Raptor (#6319) on Tue May 11 00:05:27 1999 MDT."
.