@verb #3512:"@when" any none none rxdo #6319
@program #3512:"@when" any none none
"@when"
"@when <minutes>"
"@when today"
""
"Gives a list of all players who have connected within the number of minutes specified.  If no number is given, a default of 60 minutes is used.  Typing '@when today' gives you a list for the past 24 hours."
this:update_usage(verb, player)
if (!args || (args && !args[1]))
  limit = 60 * 60
else
  if (args[1] == "today")
    limit = 60 * 60 * 24
  elseif (n = toint(args[1]))
    limit = n * 60
  else
    $msg:mtell("huh")
    return player:tell($help_utils:verb_documentation(this, verb))
  endif
endif
dudes = last = {}
for x in (players())
  if (`x.last_disconnect_time ! E_PROPNF => 0' >= time() - limit && (!x:isa($system_player) && !x:isa($guest) && !x:connected(player:isa($guardian))))
    dudes[1..0] = {{x:title(1), x, x:rank(6), ctime(x.last_disconnect_time)[1..19]}}
    last[1..0] = {x.last_disconnect_time}
  endif
  $command_utils:suspend_if_needed()
endfor
player:tellColumns({30, 5, 6, 29}, {"Player", "#", "Rank", "Last Disconnected"}, @$list_utils:sort(dudes, last))
"Last modified by Dax (#789) on Tue May  3 14:09:34 2005 MDT."
.