@verb #3512:"@room @crowd room crowd" any none none rxdo #6319
@program #3512:"@room @crowd room crowd" any none none
"Usage: @room <player name>"
"Usage: @room <location number>"
""
"Tell you the occupants of the room.  You can use either a player name, or a room number."
""
"This verb was also programmed by Lancer (#5999), and modified a little by Raptor (#6319)."
this:update_usage("crowd", player)
if (!args)
  if (caller == this)
    return player:tell("You should include the name or a player, or of a room number.")
  endif
  dest = player.location
elseif (!(x = index(args[1], "#")) && !valid(dest = $string_utils:match_local_player(args[1])))
  return player:tell("That is not a valid player.")
elseif (x)
  dest = toobj(args[1])
endif
if (is_player(dest))
  what = dest.location
else
  what = dest
endif
"Here we go...:P"
caller == this && player:tell("<PRE>")
what_name = tostr(what:title(), " (", what, ")")
spacing = this.room_index - length(what_name) - 2
each_space = spacing / 2
total = length(what_name) + spacing + 2
title_string = this.room_index - 4 - 6
second_spacing = (title_string - length(what_name)) / 2
player:tell("  Name", $string_utils:space(second_spacing, " "), what_name, $string_utils:space(second_spacing, " "), "Gender")
player:tell("--", $string_utils:space(title_string, "-"), "----------")
for x in (what.contents)
  if (is_player(x) && !x:isa($project))
    name = x.name
    idle = `x:idle_seconds(player:isa($guardian)) ! E_INVARG => 0'
    timestr = $string_utils:from_list($string_utils:explode($time_utils:english_time(idle))[1..2], " ")
    idlestr = idle >= 60 ? tostr("{{Idle: ", timestr, "}}") | ""
    gender = x.gender
    length_name = toint(length(name)) + 2
    length_gender = toint(length(gender))
    index = this.room_index - length_name - length_gender - length(idlestr)
    player:tell(x:connected(0) ? "*" | " ", " ", name, " ", idlestr, $string_utils:space(index, " "), gender)
  endif
endfor
player:tell($string_utils:space(this.room_index + 2, "-"))
player:tell(" * == Player is connected.")
caller == this && player:tell("</PRE>")
"Last modified by Dax (#789) on Thu May  5 15:55:38 2005 MDT."
.