@verb #3512:"'*" any any any rxdo #6319
@program #3512:"'*" any any any
"''<player> <message>"
"'<message>"
""
"Allows you to quickly page a player.  The first example sets a player to page.  Once you have set the player, use the second example to page the player again without the need to input their name again.  If you have not set a player, or if you type simlply '' then the next time you use ' it will act as 'say'"
""
"This verb was programmed by Manta (#7165), and hacked (and slashed) by Raptor (#6319), under the advice of Dax (#789)."
this:update_usage("'", player)
if (length(verb) > 1)
  if (verb[2] == "'")
    if (length(verb) < 3 && !args)
      if (player in this.paging)
        x = player in this.paging
        this.paging = listdelete(this.paging, x)
        this.page_to = listdelete(this.page_to, x)
      endif
      return player:tell("No one to page to?")
    endif
    whostr = verb[3..$]
    who = $string_utils:match_local_player(whostr)
    if ($command_utils:player_match_result(who, whostr)[1])
      return
    elseif (who in player.gaglist)
      return $msg:mtell("page_gag", who)
    endif
    if (!(i = player in this.paging))
      this.paging = listappend(this.paging, player)
      this.page_to = listappend(this.page_to, who)
    else
      this.page_to[i] = who
    endif
    text = argstr
  else
    text = verb[2..$] + (argstr ? " " + argstr | "")
  endif
else
  text = argstr
endif
if (length(text))
  try
    (x = this.page_to[player in this.paging]):tell("(Telepathy from " + player:title() + ") " + text)
  except (E_RANGE)
    argstr = text
    return player.location:say()
  endtry
  player:tell("You cast your thoughts to ", x:title(), !x:connected(player:isa($guardian)) ? ", but that person is sleeping...  Type '' if you'd like to use ' as a replacement for `say'." | ".")
elseif (length(verb) - 1)
else
  this:verb_documentation(this, verb)
endif
"Last modified by Raptor (#6319) on Tue May 11 00:08:11 1999 MDT."
.