@verb #340:"_handle_response" this none this rxdo #7214
@program #340:"_handle_response" this none this
caller == this || raise(E_PERM)
{c} = args
while (1)
  r = read(c)
  i = index(r, " ")
  resp = r[1..i ? i - 1 | $]
  i && (arg = r[i + 1..$])
  if (resp == "M")
    this:_report_message(arg)
  elseif (resp == "E")
    this:_report_error(arg)
  elseif (resp in {"Created", "Update-existing", "Updated"})
    path = read(c)
    entry = read(c)
    perms = read(c)
    len = toint(read(c))
    text = {}
    l = 0
    while (l < len)
      t = read(c)
      l = l + length(t) + 1
      text = {@text, t}
    endwhile
    o = this:get_object_for_path(path)
    entry = tostr(entry, value_hash(text))
    this:_set_entry(entry)
    if (entry[2] == "V")
      if (!(v = text[1] in verbs(o)))
        add_verb(o, {player, text[2], text[1]}, $string_utils:explode(text[3]))
      else
        set_verb_args(o, v, $string_utils:explode(text[3]))
        set_verb_info(o, v, {player, text[2], text[1]})
      endif
      set_verb_code(o, length(verbs(o)), text[4..$])
    elseif (entry[2] == "P")
      if (entry[2..6] == "Pname")
        o:set_name($string_utils:to_value(text[1])[2])
      elseif (`is_clear_property(o, text[1]) ! E_PROPNF' == E_PROPNF)
        add_property(o, text[1], $string_utils:to_value(text[3])[2], {player, text[2]})
      else
        set_property_info(o, text[1], {player, text[2]})
        o.(text[1]) = $string_utils:to_value(text[3])[2]
      endif
    endif
  elseif (resp == "ok")
    this:_report_message("---")
    return 1
  elseif (resp == "error")
    this:_report_error(arg[3..$])
    return 0
  elseif (resp == "Checked-in")
    dir = read(c)
    entry = read(c)
    this:_set_entry(entry)
  endif
endwhile
"Last modified by Dax (#789) on Tue May  3 14:09:31 2005 MDT."
.