@verb #3355:"chimer" this none this rxdo #3355
@program #3355:"chimer" this none this
if (!$perm_utils:controls(caller_perms(), this))
  return E_PERM
endif
fork (900 - time() % 900)
  this:chimer()
  alert = ""
  if (!this.countdown)
    alert = alert + "  NC."
  else
    if ((tdiff = this.countdown - time()) > 0)
      alert = alert + "  CD:  " + $string_utils:from_seconds(tdiff)
    else
      alert = alert + "  CD expired!"
    endif
  endif
  alert = alert + "  CP=" + tostr(length(connected_players()))
  if ($object_utils:connected(this) && idle_seconds(this) < 518400 && this.chiming == 1)
    TIME = ctime(time())
    HOUR = toint(TIME[12..13])
    DAY = TIME[1..3]
    if (HOUR < 12)
      AMPM = "AM"
    else
      AMPM = "PM"
    endif
    if (12 < HOUR)
      HOUR = HOUR - 12
    elseif (HOUR == 0)
      HOUR = 12
    endif
    MINUTE = toint(TIME[15..16])
    if (22 < MINUTE && MINUTE < 37)
      this:tell("A chirp comes from your watch marking the half hour (" + tostr(HOUR) + ")." + $string_utils:uppercase(alert))
    elseif (8 < MINUTE && MINUTE < 22)
      this:tell("A chirp comes from your watch marking quarter past the hour (" + tostr(HOUR) + ")." + $string_utils:uppercase(alert))
    elseif (37 < MINUTE && MINUTE < 52)
      this:tell("A chirp comes from your watch marking quarter to the hour (" + tostr(HOUR + 1 > 12 ? 1 | HOUR + 1) + ")." + $string_utils:uppercase(alert))
    else
      this:tell("Your watch chirps twice, which means it's " + tostr(HOUR) + " o'clock ", AMPM, " on ", DAY, "." + $string_utils:uppercase(alert))
    endif
  else
    this:tell("*** Problems: " + alert)
  endif
endfork
"Last modified by Dax (#789) on Tue May  3 14:09:34 2005 MDT."
.