@verb #330:"tell_www_body" this none this rxdo #789
@program #330:"tell_www_body" this none this
"Print a custom header message."
caller == this || raise(E_PERM)
player:tell("<IMG SRC=\"http://files.moo.ca/pics/mc_who.jpg\" WIDTH=170 HEIGHT=234 ALIGN=\"right\" ALT=\"[Who is on the MOO?]\">")
player:tell("<H2>The following players are currently online:</H2>")
"args[3] is a list of options that were determined in tell_www_page."
options = args[$]
rank = "Rank" in options
location = "Location" in options
times = "Times" in options
network = "Network" in options && player.user:isa($guardian)
email = player.user.wizard && "Email" in options
line = {"Player"}
rank && (line = {@line, "Rank"})
location && (line = {@line, "Location"})
times && (line = {@line, "Connect Time", "Idle Time"})
network && (line = {@line, "Network"})
email && (line = {@line, "E-mail"})
info = {line}
for dude in (setremove(connected_players(), player))
  $command_utils:suspend_if_needed()
  if (dude:isa($player))
    line = {tostr("<a href=\"/~", dude.name, "\" class=\"who\">", `dude:title() ! ANY => dude.name', "</a> (", dude, ")")}
  else
    line = {tostr("<a href=\"", $www.url, $www:find_ref(dude), "\" class=\"who\">", `dude:title() ! ANY => dude.name', "</a> (", dude, ")")}
  endif
  rank && (line = {@line, $object_utils:rank(dude)})
  if (location)
    loc = dude.location
    line = {@line, tostr("<a href=\"", $www.url, $www:find_ref(loc), "\" class=\"who\">", loc:title(), "</a>")}
  endif
  if (times)
    line = {@line, $string_utils:from_seconds(dude:connected_seconds()), $string_utils:from_seconds(dude:idle_seconds())}
  endif
  if (network)
    line = {@line, $string_utils:connection_hostname(connection_name(dude))}
  endif
  if (email)
    address = `dude:isa($webber) ? dude.user.email_address | dude.email_address ! E_PROPNF'
    line = {@line, address ? tostr("<A HREF=\"/finger?", address, "\">", address, "</A>") | "&nbsp"}
  endif
  info = {@info, line}
endfor
if (length(info))
  player:tellColumns($list_utils:make(length(info[1])), @info)
else
  player:tell("I don't see anyone online.")
endif
player:tell("<FORM>Choose what columns to show:")
player:tell("<BR><INPUT TYPE=\"checkbox\" NAME=\"Rank\"", rank ? " CHECKED>" | ">", " Rank")
player:tell("<BR><INPUT TYPE=\"checkbox\" NAME=\"Location\"", location ? " CHECKED>" | ">", " Location")
player:tell("<BR><INPUT TYPE=\"checkbox\" NAME=\"Times\"", times ? " CHECKED>" | ">", " Times")
if (player.user:isa($guardian))
  player:tell("<BR><INPUT TYPE=\"checkbox\" NAME=\"Network\"", network ? " CHECKED>" | ">", " Network Connection")
  if (player.user.wizard)
    player:tell("<BR><INPUT TYPE=\"checkbox\" NAME=\"Email\"", email ? " CHECKED>" | ">", " E-mail Address")
  endif
endif
player:tell("<BR><INPUT TYPE=\"submit\" VALUE=\"Submit.\"></FORM>")
if (!player.user_agent)
  "The GET request may arrive before the User_Agent info."
  suspend(1)
endif
if (index(player.user_agent, "Mozilla"))
  player:tell("<P>This page will automatically reload every ", $tcm ? "five minutes." | "minute.")
  player:tell(this.addfunction)
  player:tell("<HR><P><A HREF='javascript:addNetscapePanel();'><IMG SRC='", $www:fileURL(this, "add-button.gif"), "' BORDER=0 height=45 width=100 ALT='[Add Sidebar]'></A> Add the Moo who listing to your Mozilla/Netscape 6 sidebar.")
  player:tell("<P><a href='", $www:fileURL(this, "who.cdf"), "'><img src='", $www:fileURL(this, "addtodesktop.gif"), "' width=136 height=20 border=0 alt='[Add to IE Desktop]'></a> Add to IE Active Desktop.")
endif
"Last modified by Dax (#789) on Thu May  5 15:58:43 2005 MDT."
.