@verb #3309:"@seatname" any is any rxd #8438
@program #3309:"@seatname" any is any
"Syntax: @seatname <old-seat-name> is <new-seat-name>[,<new-seat-name-alias>...]"
"Change the name and aliases of a given seat.  Seperate new aliases with a comma (,).  If you don't give any new names, it will just tell you what the old names are."
if (!this:controlled_by(player))
  player:tell("You don't own the room, and can't do any interior decorating.  Sorry!")
  return
endif
if (!(check = this:match_seat(dobjstr)))
  player:tell("There's no seat named '", dobjstr, "' in ", this.name, ".")
  return
elseif ("is" in args == length(args))
  player:tell("names of '", dobjstr, "' are: ", toliteral(this:seatlist()[check][1]))
elseif (!iobjstr)
  player:tell("What do you want to name the seat.  You can't use a blank name.")
else
  names = $string_utils:explode(iobjstr, ",")
  for match in (listdelete(this:seatlist(), check))
    if (typeof(match[1]) == $LIST && (bad = $set_utils:intersection(names, match[1])))
      player:tell("There's already another seat named \"", bad[1], "\".")
      return
    elseif (typeof(match[1]) == $STR && (i = match[1] in names))
      player:tell("There's already another seat named \"", names[i], "\".")
      return
    endif
  endfor
  "New code added by Dax when listset function was removed."
  seatlist = this:seatlist()
  names = length(names) > 1 ? names | names[1]
  seatlist[check][1] = names
  this:set_seatlist(seatlist)
  "Original code"
  "this:set_seatlist(listset(seatlist = this:seatlist(), listset(seatlist[check], names = length(names) > 1 ? names | names[1], 1), check))"
  player:tell("\"", dobjstr, "\" changed to ", toliteral(names))
endif
"Last modified by Dax (#789) on Tue May 17 13:59:09 2005 MDT."
.