@verb #3309:"@seated @sit @osit @stand @ostand" any is any rxd #8438
@program #3309:"@seated @sit @osit @stand @ostand" any is any
"Syntax: @seated <chair> is <message> - Change the message displayed"
"                           when someone is sitting."
"       @sit <chair> is <message>    - Change the message displayed"
"                           to someone who sits."
"       @osit <chair> is <message>   - Change the message displayed"
"                           when someone else sits."
"       @stand <chair> is <message>  - Change the message displayed"
"                           to someone who stands."
"       @ostand <chair> is <message> - Change the message displayed"
"                           when someone else stands."
"If you don't give a message, the current message will be displayed to you."
if (!this:controlled_by(player))
  player:tell("You don't own the room, and can't do any interior decorating -  sorry!")
  return
endif
msg = verb[2..length(verb)] + "list_msgs"
if ((check = this:match_seat(dobjstr)) == $ambiguous_match)
  return player:tell("I don't know which \"", dobjstr, "\" you mean.")
elseif (!check)
  return player:tell("There's no seat named '", dobjstr, "' in ", this.name, ".")
elseif ("is" in args == length(args))
  player:tell(verb, " message for '", dobjstr, "' is \"", this.(msg)[check], "\"")
else
  player:tell("You set the ", verb, " message for '", dobjstr, "'.")
  this.(msg)[check] = iobjstr
endif
.