@verb #3309:"@detail-desc*ription @detaildesc*ription @detail-name @detailname" any any any rdo #8438
@program #3309:"@detail-desc*ription @detaildesc*ription @detail-name @detailname" any any any
if (!this:controlled_by(player))
  return player:tell(E_PERM, "; only ", $string_utils:nn(this.owner), " can re-decorate.")
elseif (!args)
  return player:tell("Syntax: ", verb, " <detail> [is <description>]")
endif
detail = this:match_detail(dobjstr)
if (detail == $failed_match)
  return player:tell("\"", dobjstr, "\" isn't a detail here; try somewhere else.")
else
  if (index(verb, "desc"))
    if (!prepstr && !iobjstr)
      this.details[detail][2] = $command_utils:read_lines(tostr(this.details[detail][1][1], "'s new description"))
    else
      this.details[detail][2] = iobjstr
    endif
    return player:tell(this.details[detail][1][1], "'s description set.")
  else
    if (!iobjstr)
      return player:tell("Syntax: ", verb, " <detail> is <name,alias,alias. . .>")
    endif
    names = $string_utils:explode(iobjstr, ",")
    for x in (names)
      if (!this:check_integrated(x))
        return player:tell("A detail or seat named \"", x, "\" already exists here.")
      endif
      $command_utils:suspend_if_needed()
    endfor
    this.details[detail][1] = {}
    for name in (names)
      this.details[detail][1] = setadd(this.details[detail][1], name)
      $command_utils:suspend_if_needed()
    endfor
    return player:tell("Detail renamed.")
  endif
endif
"Last modified by Dax (#789) on Thu Nov  8 11:53:54 2001 MST."
.