@verb #3152:"demote" this none this rxdo #3152
@program #3152:"demote" this none this
"Demote all the wizzen except $slacker"
caller == this || raise(E_PERM)
demote = setremove($wiz:leaves(), $slacker)
demote = setremove(demote, this)
for x in (demote)
  chparent(x, $prog)
  for y in [#0..#1000]
    if (!$recycler:valid(y))
      continue
    endif
    if (y.owner == x)
      y.owner = $slacker
    endif
    for z in [1..length(verbs(y))]
      vi = verb_info(y, z)
      if (vi[1] == x)
        vi[1] = $slacker
        `set_verb_info(y, z, vi) ! ANY => player:tell(y, ":", z)'
        vc = {@verb_code(y, z), tostr("\"This verb previously owned by ", $su:nn(x), ", and chowned to $slacker upon dewizarding (", ctime(), ").\";")}
        set_verb_code(y, z, vc)
      endif
      $cmd_utils:suspend_if_needed(0)
    endfor
    for z in (properties(y))
      pi = property_info(y, z)
      if (pi[1] == z)
        pi[1] = $slacker
        set_property_info(y, z, pi)
      endif
      $cmd_utils:suspend_if_needed(0)
    endfor
    $cmd_utils:suspend_if_needed(0)
  endfor
  for y in (x.owned_objects)
    if (y:isa($guardian_phaser))
      player:tell("Located guardian phaser ", $su:nn(y), ". Chparenting...")
      chparent(y, $phaser)
    endif
    $cmd_utils:suspend_if_needed(0)
  endfor
  x.wizard = 0
  $cmd_utils:suspend_if_needed(0)
endfor
.