@verb #3135:"@manta-check" any none none rdo #55
@program #3135:"@manta-check" any none none
"Copied from Lao-Tzu (#8084):@manta-check May  1 10:29:34 1997"
"Whee! :)"
if (argstr)
  timetocheck = time() - $time_utils:parse_english_time_interval(argstr)
else
  "Default to last manta connect. Dax's idea."
  timetocheck = #7165.last_connect_time
endif
things = $hacker.owned_objects
this:tell("*** @manta-check since ", ctime(timetocheck), " ***")
for x in (children($wiz))
  things = {@things, @x.owned_objects}
  $command_utils:suspend_if_needed()
endfor
"Ok, check through ALL the things in 'things', and all their verbs to find anything modified by manta within since timetocheck."
for q in (things)
  for x in [1..length(`verbs(q) ! E_PERM => {}')]
    code = `verb_code(q, x) ! E_PERM => {}'
    line = `code[$] ! ANY => "Blank verb."'
    if (index(line, "manta") && index(line, "#7165"))
      "Woo, last modified by manta."
      timemod = $time_utils:From_ctime(line[$ - 30..$ - 3])
      if (timemod > timetocheck)
        this:tell("Manta modified ", q, ":\"", verbs(q)[x], "\" recently. (", ctime(timemod), ")")
      endif
    endif
    $command_utils:suspend_if_needed()
  endfor
  $command_utils:suspend_if_needed()
endfor
this:tell("*** Done ***")
"Last modified by Dax (#789) on Sat May 16 14:19:59 1998 EDT."
.