@verb #310:"tell_www_body" this none this rxdo #60
@program #310:"tell_www_body" this none this
caller == this || raise(E_PERM)
player:tell("<CENTER>")
player:tell($html_utils:tabbar(4, "Search", "/search", "Grep", "/grep", "Tree", "/tree", "Audit", "/audit", "Names", "/names"))
player:tell("</CENTER>")
if (who = $www:parse_GET("isindex"))
  who = this:match_who(who)
endif
if (parent = $www:parse_GET("create"))
  this:do_create(parent)
elseif (who == E_PROPNF)
  "Display the opening screen."
  player:tell({"<H2>Audit a player.</H2>", "Whom do you wish to audit?<BR>", this:who_form()})
  if (player.user != $no_one)
    player:tell("You can customize the audit page by clicking on <B>Setup</B> in the toolbar.")
  endif
else
  "Audit a particular person."
  player:tell("<H2>", $su:nn(who), "'s audit:</H2>")
  {user_columns, user_sort, user_quota, user_create_recycle} = this:get_data(player.user)
  this:tell_audit(who, user_columns, user_sort)
  player:tell("<HR>")
  if (player.user == who && who != $no_one || user_quota)
    player:tell("<H3>Quota:</H3>")
    this:tell_quota(who)
  endif
  if (player.user == who && who != $no_one || user_create_recycle)
    player:tell({"<TABLE BORDER=0 WIDTH=100%><TR><TD>", "<H3>Create an object:</H3><FORM ACTION=\"/audit\" METHOD=\"get\">Create a <INPUT TYPE=\"input\" NAME=\"create\" VALUE=\"$thing\">. <INPUT TYPE=\"Submit\" VALUE=\"Create!\"></FORM>", "</TD><TD>", "<H3>Recycle an object:</H3><FORM ACTION=\"/recycler\" METHOD=\"get\">Recycle object number <INPUT TYPE=\"input\" NAME=\"recycle\" SIZE=6 VALUE=\"#\">. <INPUT TYPE=\"Submit\" VALUE=\"Recycle!\"></FORM>", "</TD></TR></TABLE>"})
  endif
  player:tell({"<HR><H3>Audit another player:</H3>", this:who_form(who)})
endif
"Last modified by Dax (#789) on Thu Sep 26 07:17:27 2002 MDT."
.