@verb #310:"tell_quota" this none this rxdo #789
@program #310:"tell_quota" this none this
player:isa($webber) || raise(E_PERM)
{who} = args
if (player.user:isa($guardian) && caller == this)
  "Allow for quota hacking."
  guard = 1
  if ((qobj = $www:parse_POST("qobj")) && (qvm = $www:parse_POST("qvm")) && (qfs = $www:parse_POST("qfs")))
    "Let's fiddle with someone's quota."
    if (player.referer && $www:previous_object() != this)
      "We have an unknown form refering a quota change to us..."
      $msg:mtell("www_error", "Warning!  Previous page doesn't appear to be this one!")
      player:tell("For security reasons the quota change will not be executed.  Refering page: [", player.referer, "]")
    else
      who.max_obj = toint(qobj)
      who.max_vm = toint(qvm) * $kb
      who.max_fs = toint(qfs) * $kb
      player:tell("<B>Quota change successful.</B><BR>")
    endif
  endif
else
  guard = 0
endif
set_task_perms($no_one)
type = {"", "Object:<BR>(objects)", "Byte:<BR>(kilobytes)", "Disk:<BR>(kilobytes)"}
total = {"<B>Total:</B>", who:_get_max_obj(), who:_get_max_vm() / $kb, who:_get_max_fs() / $kb}
free = {"<B>Free:</B>", who:free_objects(), who:free_bytes() / $kb, who:free_dbytes() / $kb}
used = {"<B>Used:</B>", total[2] - free[2], total[3] - free[3], total[4] - free[4]}
if (guard)
  total = {total[1], tostr("<INPUT NAME=\"qobj\" VALUE=\"", total[2], "\" SIZE=5>"), tostr("<INPUT NAME=\"qvm\" VALUE=\"", total[3], "\" SIZE=5>"), tostr("<INPUT NAME=\"qfs\" VALUE=\"", total[4], "\" SIZE=5>")}
endif
guard && player:tell("<FORM METHOD=\"post\">")
player:TellColumns(3, {1, 1, 1, 1}, type, used, free, total)
guard && player:tell("<INPUT TYPE=\"submit\" VALUE=\"Change quota.\"></FORM>")
"Last modified by Dax (#789) on Tue May  3 14:09:31 2005 MDT."
.