@verb #310:"match_who" this none this rxdo #60
@program #310:"match_who" this none this
{name} = args
who = toobj(name)
if (valid(who) && who != #0)
  if (who:isa($accountable))
    "That was easy!"
    return who
  else
    $msg:mtell("www_error", $su:nn(who) + " is not a player!")
    return E_PROPNF
  endif
endif
"Who wasn't a number, lets try matching a name."
who = $su:match_player(name, player.user)
if (who == $failed_match)
  "Dunno who you're talking about."
  $msg:mtell("www_error", "There is no player called '" + name + "'.")
  return E_PROPNF
elseif (who == $ambiguous_match)
  "Offer the choices."
  $msg:mtell("www_error", "'" + name + "' is ambiguous.")
  player:tell("Which one of the following did you wish to audit:")
  whos = {}
  for who in ($player_db:find_all(name))
    whos = {@whos, tostr("<A HREF=\"/audit?", toint(who), "\">", $su:nn(who), "</A>")}
  endfor
  player:tell($su:english_list(whos, "[none]", " or "))
  return E_PROPNF
elseif (who == $nothing)
  "Who was an empty string."
  return E_PROPNF
endif
"Success!"
return who
"Last modified by Dax (#789) on Tue May  3 14:09:31 2005 MDT."
.