@verb #2978:")gag )ungag" any none none rxdo #7921
@program #2978:")gag )ungag" any none none
$perm_utils:is_called_from(player, "my_huh") || raise(E_PERM)
if (args[1] == "all")
  if (verb[2] == "g")
    player:tell("You go into silent mode.")
    argstr = $msg:substitute("has gone into silent mode.  %S no longer hears anything on this channel.")
    this:(")mote")()
  else
    player:tell("You re-enter active mode.")
    argstr = "has returned from silent mode."
    this:(")mote")()
  endif
  for y in [1..length(this.gags)]
    if (this.gags[y][1] == player)
      return this.gags[y][2] = verb[2] == "g" ? 1 | 0
    endif
  endfor
  this.gags = {@this.gags, {player, verb[2] == "g" ? 1 | 0, {}}}
else
  who = $su:match_local_player(args[1])
  if (who == #-3)
    return player:tell("You don't see '", args[1], "' here.")
  endif
  if (!(who in this.listeners))
    return player:tell("You can't gag someone who isn't even on CatsTalk!")
  endif
  for y in [1..length(this.gags)]
    if (this.gags[y][1] == player)
      if (verb[2] == "g")
        player:tell("You add them to your gag list.")
        return this.gags[y][3] = {@this.gags[y][3], toobj(who)}
      else
        player:tell("You remove them from your gag list.")
        return this.gags[y][3] = {@setremove(this.gags[y][3], toobj(who))}
      endif
    endif
  endfor
  if (verb[2] == "g")
    this.gags = {@this.gags, {player, 0, {toobj(who)}}}
    return player:tell("You add them to your gag list.")
  else
    return player:tell("You are not gagging anyone.")
  endif
endif
"Last modified by Lao-Tzu (#8084) on Tue Jun 26 08:37:55 2001 MDT."
.