@verb #2805:"gsay gmote gwho" any any any rxdo #2526
@program #2805:"gsay gmote gwho" any any any
if (verb != "gwho")
  for x in (#7921.group)
    if (verb == "gsay")
      x:tell("[Group]: ", player:title(), " says, \"", argstr, "\"")
    else
      x:tell("[Group]: ", player:title(), " ", argstr)
    endif
  endfor
  return
endif
dudes = {}
for m in (#7921.group)
  time = player:ctime(m.last_disconnect_time)
  dudes = {@dudes, tostr($string_utils:left(m:title(), 15), " ", m, "  ")}
  if (m:connected())
    dudes[$] = tostr(dudes[$], $string_utils:right(tostr(idle_seconds(m) / 60 != 0 ? tostr(idle_seconds(m) / 60, "m") | "", idle_seconds(m) - 60 * (idle_seconds(m) / 60), "s"), 12), "  ")
  else
    dudes[$] = tostr(dudes[$], $string_utils:right(tostr(time[1..3], "-", time[9..10], "@", time[12..16]), 12), "  ")
  endif
  dudes[$] = tostr(dudes[$], "  ", $string_utils:left(m.location:Title(), 20), " ", m.location)
endfor
player:tell("Name                  Idle/Discon      Location")
player:tell("---------------------  ------------    --------------------------")
for m in (dudes)
  player:tell(m)
endfor
player:tell("-----------------------------------------------------------------")
"Last modified by Catspaw (#7921) on Mon Apr 19 16:05:27 1999 MDT."
.