@verb #26:"RCPT" any none none rdo #55
@program #26:"RCPT" any none none
"RCPT TO: <recipient> [ <parameters> ]"
"    Specifies the recipient.  Can be used any number of times."
"    Parameters are ESMTP extensions.  Currently not supported."
if (this.state < 2)
  return player:tell("503 MAIL required")
elseif (this.state > 3)
  return player:tell("503 Expecting either RCPT or DATA command.")
endif
"dobjstr should be of the form 'TO: <slacker@moo.ca>', or 'TO: <slacker>'"
"m = match(dobjstr, \"^[Tt][Oo]:[ ]*<%([^>]+%)>$\");"
"The <> should be optional, and match is case insensitive by default -- Dax."
m = match(dobjstr, "^TO:[ ]*<?%([^>]+%)>?$")
if (!m)
  return player:tell("501 Unable to parse ", dobjstr)
endif
to = dobjstr[m[3][1][1]..m[3][1][2]]
to_split = $network:parse_address(to)
if (!(to_split[2] in {"", "moo", $site, "moo.ca"}))
  "For some reason, we don't seem to get passed the other places the mail gets sent to.  I don't get it.  -whiz"
  this.other_headers = {@this.other_headers, dobjstr}
  return player:tell("551 Message not local; please try <", to, ">")
endif
if (to_split[1] == "me")
  return player:tell("550 User <", to_split[1], "> not found.")
endif
if (to_split[1] in this.daemon.special_rcpts)
  really_to = {this.daemon, to_split[1]}
elseif (valid(p = $mail_agent:match_recipient(to_split[1])))
  really_to = p
elseif (is_player(p = toobj(to_split[1])))
  really_to = p
elseif (to_split[1] in this.daemon.special_rcpts)
  really_to = {this.daemon, to_split[1]}
else
  return player:tell("550 User <", to_split[1], "> not found.")
endif
if (typeof(really_to) == $OBJ && (!really_to.accept_public_email && (typeof(this.from) != OBJ || this.from != #-3) || `this.from in really_to.smtp_blocked_addresses ! ANY => 0'))
  return player:tell("550 Recipient '", $string_utils:nn(really_to), "' does not accept email from non-players.  Sorry.")
endif
this.to = setadd(this.to, really_to)
this.state = 3
player:tell("250 Recipient '", typeof(really_to) == $OBJ ? $su:nn(really_to) | tostr(really_to[2]), "' OK.")
"Last modified by Lao-Tzu (#8084) on Sat Dec 29 10:31:06 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Tue May  3 13:49:39 2005 MDT."
.