@verb #2633:"@ve" any none none rd #2633
@program #2633:"@ve" any none none
$dperms:only_owner()
i = index(argstr, ":")
if (!argstr || !i)
  return player:tell("Syntax: ", verb, " dobj:verb")
endif
{dobj, verb} = {argstr[1..i - 1], argstr[i + 1..$]}
dobj = toobj((p = player):my_match_object(dobj))
if (!$recycler:valid(dobj))
  return p:tell("[", this, ":@ve] Can't match dobj. ", dobj)
elseif (`info = verb_info(dobj, verb) ! ANY => "bad"' == "bad")
  return p:tell("[", this, ":@ve] Can't match verb. ", verb)
endif
args = verb_args(dobj, verb)
p:tell("---")
p:tell({"1] Change Owner", "2] Change Perms", "3] Change Names", "4] Change Args", "5] Change Code", "6] List Code"})
p:tell("---")
menu = toint($command_utils:read(""))
if (menu < 1 || menu > 6)
  return p:tell("Not a valid menu item. Pick between 1 and 5 please.")
elseif (menu == 1)
  p:tell("New owner is?")
  pick = toobj($command_utils:read())
  if (!$recycler:valid(pick))
    return p:tell("[", this, ":@ve] Can't match dobj. ", dobj)
  endif
  info[1] = pick
elseif (menu == 2)
  p:tell("New perms are?")
  pick = $command_utils:read()
  info[2] = pick
elseif (menu == 3)
  p:tell("New name is?")
  pick = $command_utils:read()
  info[3] = pick
elseif (menu == 4)
  types = {"AAA", "NNN", "ANN", "TNT"}
  equiv = {{"any", "any", "any"}, {"none", "none", "none"}, {"any", "none", "none"}, {"this", "none", "this"}}
  p:tell("Choices are: ", $su:english_list(types))
  pick = $command_utils:read()
  if (!(loc = pick in types))
    return player:tell("Valid types were as listed.")
  endif
  args = equiv[loc]
  set_verb_args(dobj, verb, args)
elseif (menu == 5)
  p:tell("Please input new code..")
  code = $command_utils:read_lines()
  ERR = set_verb_code(dobj, verb, code)
  for line in (ERR)
    p:tell(line)
  endfor
  p:tell("Verb code set.")
elseif (menu == 6)
  p:tell("@program ", dobj, ":", verb)
  p:tell(verb_code(dobj, verb))
  p:tell(".")
endif
if (menu in {1, 2, 3})
  set_verb_info(dobj, verb, info)
  info = verb_info(dobj, info[3])
  p:tell("Info: ", toliteral(info))
endif
"Last modified by Dax (#789) on Tue May  3 14:09:34 2005 MDT."
.