@verb #2633:"@note*s @note-kill" any any any rxd #2633
@program #2633:"@note*s @note-kill" any any any
{su, p} = {$string_utils, player}
ln = length(this.notes)
if (player != this)
  "Someone's leaving me a note!"
  note = $command_utils:read()
  if (!note && "<shrugs>")
    return
  endif
  player:tell(this.note_msg)
  this.notes = {@this.notes, note + " " + su:nn(p)}
  this:tell("You have a new note from ", p.name, "!")
elseif (!argstr && ln && verb != "@note-kill")
  for line in [1..ln]
    p:tell(su:left(tostr(line), 2), " :  ", this.notes[line])
  endfor
  return
elseif (!argstr && verb == "@note-kill")
  return p:tell("@note-kill [note-num]")
elseif (!argstr)
  return p:tell("No notes.")
elseif ((n = toint(argstr)) > 0)
  if (n > ln)
    return p:tell("Last valid note is: ", ln)
  elseif (verb == "@note-kill")
    this.notes = listdelete(this.notes, n)
    return p:tell("Note ", n, " deleted.")
  endif
  return p:tell(su:left(n, 2), " :  ", this.notes[n])
elseif ("adding a note")
  this.notes = {@this.notes, argstr}
  p:tell("Note ", ln + 1, " added: ", argstr)
endif
"Last modified by Dax (#789) on Tue May  3 14:09:34 2005 MDT."
.