@verb #2599:"to_english" this none this rxdo #9682
@program #2599:"to_english" this none this
couplets = {{"e", "ae"}, {"t", "tz"}, {"r", "mn"}, {"q", "tcho"}, {"z", "xx"}}
others = {{"b", "g"}, {"c", "k"}, {"d", "t"}, {"f", "v"}, {"g", "b"}, {"h", "y"}, {"j", "q"}, {"l", "p"}, {"m", "w"}, {"n", "r"}, {"o", "u"}, {"p", "l"}, {"u", "o"}, {"v", "f"}, {"w", "m"}, {"x", "z"}, {"y", "h"}, {"a", "a"}, {"s", "s"}}
ret = {}
if (typeof(args[1]) == $LIST)
  for x in (args[1])
    ret = {@ret, this:(verb)(x)}
  endfor
  return ret
endif
STR = ""
nargs = args[1]
args[1] = $su:lowercase(args[1])
apos = doub = 0
for y in [1..length(args[1])]
  if (doub)
    doub = 0
    continue
  endif
  if (args[1][y] == "'")
    apos = 1
    continue
  endif
  iscap = strcmp(nargs[y], args[1][y])
  nextTwo = `args[1][y..y + 1] ! ANY => ""'
  if (li = listiassoc(nextTwo, couplets, 2))
    STR = STR + (iscap ? $su:capitalise(couplets[li][1]) | couplets[li][1])
    if (apos)
      apos = 0
      STR = STR + couplets[li][1]
    endif
    doub = 1
  elseif (li = listiassoc(args[1][y], others, 2))
    STR = STR + (iscap ? $su:capitalise(others[li][1]) | others[li][1])
  else
    STR = STR + args[1][y]
  endif
endfor
this.owner:tell("Pak-to-Eng: ", STR)
return STR
"Last modified by Dax (#789) on Tue May  3 13:45:05 2005 MDT."
.