@verb #2570:"@ctrl-show:*" any none none rd #2570
@program #2570:"@ctrl-show:*" any none none
"Multiplexing maintenance command"
if (player != this)
  return
endif
prefix = tostr("*** ctrl:", verb[12..$], " ")
if (!valid(dobj = this:my_match_object(dobjstr)))
  player:tell(prefix, "Invalid object: ", dobjstr)
  player:tell(prefix, ".")
  return
endif
try
  verbs = verbs(dobj)
  for v in [1..length(verbs)]
    try
      {owner, perms, names} = verb_info(dobj, v)
      {dspec, pspec, ispec} = verb_args(dobj, v)
      hash = value_hash(verb_code(dobj, v))
      if (pspec != "none" && pspec != "any")
        pspec = $code_utils:short_prep(pspec)
      endif
      perms = perms + "v"
      r = $string_utils:from_list({perms, owner, dspec, pspec, ispec, hash}, " ") + ": " + names
    except e (ANY)
      r = "ve " + toliteral(e[1]) + ": " + verbs[v]
    endtry
    player:tell(prefix, r)
    $command_utils:suspend_if_needed(0)
  endfor
  for p in (properties(dobj))
    pi = `property_info(dobj, p) ! ANY'
    if (typeof(pi) != $LIST)
      r = "pe " + toliteral(pi) + ": " + p
    else
      {owner, perms} = pi
      r = tostr(perms, "p ", owner, ": ", p)
    endif
    player:tell(prefix, r)
    $command_utils:suspend_if_needed(0)
  endfor
except e (ANY)
  player:tell(prefix, e[1])
endtry
player:tell(prefix, ".")
"Last modified by Dax (#789) on Wed May  4 06:46:02 2005 MDT."
.