@verb #24:"render" this none this rxdo #789
@program #24:"render" this none this
{data} = args
output = {""}
tag = ""
for x in (data)
  if (typeof(x) == $STR)
    if (!tag && `x[1] ! E_RANGE' == "<")
      tag = x[2..$ - 1]
    else
      output[$] = output[$] + x
    endif
  else
    chunk = {@this:(verb)(x)}
    output[$] = output[$] + chunk[1]
    length(chunk) > 1 && (output = {@output, @chunk[2..$]})
  endif
endfor
if (tag)
  name = tag[1..index(tag, " ") || $]
  original = length(output) == 1 ? {tostr("&lt;", tag, "&gt;", output[1], "&lt;/", tag, "&gt;")} | {tostr("&lt;", tag, "&gt;", output[1]), @output[2..$ - 1], tostr(output[$], "&lt;/", tag, "&gt;")}
  output = `this:("render_" + name)(output, tag) ! E_VERBNF => this:handle_unknown_tag(output, tag, original)'
  "Changed by Cecil to make it uglier (it calls handle_unknown_tag instead of render_*)"
  "This makes adding new renders easier, and allows simplification of an even uglier block of code that was originally in $connectable:html2text."
endif
return output
"Last modified by Dax (#789) on Tue May  3 13:43:06 2005 MDT."
.