@verb #24:"notify(backup)" this none this rxdo #55
@program #24:"notify(backup)" this none this
"Copied from Generic Connectable Object (#24):notify by Slacker (#55)Feb 18 13:10:01 2000"
if (caller != this && !caller_perms():controls(this))
  "Never remove this check.  It is important, believe it or else."
  raise(E_PERM)
endif
if (args)
  ntext = args[1]
  text = this.output_wrap ? $string_utils:wrap(ntext, this.output_linelength) | ntext
elseif (text = this.output_more_buffer)
  this.output_more_buffer = {}
  this.output_more_linesleft = this.output_more_pagelength
else
  return
endif
$code_utils:semaphore_enter("notify")
if (this.output_more_buffer)
  this.output_more_buffer = {@this.output_more_buffer, @text}
else
  tl = {@text}
  dosub = !index(verb, "direct")
  for line in (tl)
    dosub && (line = strsub(line, "<", "&lt;"))
    dosub && (line = strsub(line, ">", "&gt;"))
    if (!this.output_more_pagelength || this.output_more_linesleft > 0)
      index(verb, "bin") || (line = encode_binary(line))
      line = $msg:process_notify(line, this.output_accent_mode)
      try
        set_connection_option(this, "binary", 1)
        notify(this, line + this.output_eol)
        set_connection_option(this, "binary", 0)
        this.output_more_linesleft = this.output_more_linesleft - 1
      except (E_INVARG)
        "You aren't connected?"
      endtry
    else
      this.output_more_buffer = {@this.output_more_buffer, line}
    endif
    $cmd_utils:suspend_if_needed()
  endfor
  if (this.output_more_buffer)
    notify(this, tostr("--- More --- Type [enter], flush, or rest --- ", length(this.output_more_buffer), " lines left ---"))
  endif
endif
$code_utils:semaphore_exit("notify")
.