@verb #24:"@cliento*ptions @client-o*ptions" any any any rdo #55
@program #24:"@cliento*ptions @client-o*ptions" any any any
"@client-option <option> [is] <value>   sets <option> to <value>"
"@client-option <option>=<value>  sets <option> to <value>"
"@client-option +<option>         sets <option>   (usually equiv. to <option>=1"
"@client-option -<option>         resets <option> (equiv. to <option>=0)"
"@client-option <option>          displays value of <option>"
if (!args)
  player:tell("Current client options:")
  player:tell("   pagelength    Pagelength is set to: ", this.output_more_pagelength)
  player:tell("   linelength    linelength is set to: ", abs(this.output_linelength))
  player:tell(this.output_linelength < 0 ? "  +wrap          Text wrapping is on." | "  -wrap          Text wrapping is off.")
  player:tell("   accents       Accent translation mode is: ", this.output_accent_mode)
  return
elseif (length(args) == 1 && !(argstr[1] in {"!", "+", "-"}) && !index(argstr, "="))
  args[1] == "type" && player:tell("   type    [none]")
  args[1] == "pagelength" && player:tell("   pagelength    Pagelength is set to: ", this.output_more_pagelength)
  args[1] == "linelength" && player:tell("   linelength    linelength is set to: ", this.output_linelength)
  args[1] == "wrap" && player:tell(this.output_wrap ? "  +wrap          Text wrapping is on." | "  -wrap          Text wrapping is off.")
  args[1] == "accents" && player:tell("   accents       Accent translation mode is: ", this.output_accent_mode)
  return
elseif (i = index(argstr, "="))
  name = argstr[1..i - 1]
  val = `argstr[i + 1..$] ! E_RANGE => ""'
elseif (argstr[1] in {"+", "-", "!"})
  try
    name = argstr[2..$]
  except (E_RANGE)
    return player:tell("I couldn't understand: ", argstr)
  endtry
  val = argstr[1] == "+"
else
  "It's either @client-o foo is bar, or @client-o foo bar"
  name = args[1]
  val = argstr[length(name) + index(argstr, name)..$]
  m = match(argstr, tostr("^ *", name, " +is +%(.+%)$")) || match(argstr, tostr("^ *", name, " +%(.+%)$"))
  if (!m)
    return player:tell("I couldn't understand \"", argstr, "\".")
  endif
  val = argstr[m[3][1][1]..m[3][1][2]]
endif
if (name == "pagelength")
  this.output_more_pagelength = toint(val)
  player:tell("Pagelength is set to: ", this.output_more_pagelength)
elseif (name == "linelength")
  this.output_linelength = toint(val)
  player:tell("linelength is set to: ", this.output_linelength)
elseif (name == "wrap")
  this.output_wrap = !this.output_wrap
  player:tell(this.output_wrap ? "Text wrapping is on." | "Text wrapping is off.")
elseif (name == "accents")
  if (val in {"html", "stripped", "iso", "dos"})
    this.output_accent_mode = val
    player:tell("Accent translation mode is: ", this.output_accent_mode)
  else
    player:tell("Valid accent modes are: stripped, html, iso, dos")
  endif
else
  player:tell("Unknown option.")
endif
"Last modified by Dax (#789) on Tue May  3 14:09:30 2005 MDT."
.