@verb #242:"@add @remove" this none none rdo #7788
@program #242:"@add @remove" this none none
if (player != this.owner)
  return player:tell("You can't do that... You're not smart enough!")
endif
if (verb == "@add")
  player:tell("Add a new feature to #242?")
else
  player:tell("Remove a feature from #242?")
endif
ans = $cmd_utils:yes_or_no()
if (ans == 1)
  pfxs = {"msg_", "msg_o", "msg_p", "msg_t", "msg_l"}
  if (verb == "@add")
    name = $cmd_utils:read("the name of the new social")
  else
    name = $cmd_utils:read("the name of the social to remove")
  endif
  for x in (pfxs)
    if (verb == "@add")
      line = $cmd_utils:read(tostr(x, name))
      player:tell()
      add_property(this, tostr(x, name), line, {this.owner, "rc"})
    else
      player:tell("Deleting ", tostr(x, name), "...")
      delete_property(this, tostr(x, name))
    endif
  endfor
  vi = verb_info(this, "!!!")
  if (verb == "@add")
    set_verb_info(this, "!!!", {vi[1], vi[2], tostr(vi[3], " ", name)})
  else
    set_verb_info(this, "!!!", {vi[1], vi[2], $su:from_list(setremove($su:explode(vi[3]), name), " ")})
  endif
  player:tell("Done.")
else
  player:tell("Aborted.")
endif
"Last modified by Leo (#8383) on Thu Mar 18 07:31:44 1999 MST."
.