@verb #2250:"@ren*ame @ren*omme 2rename @copy*! 2copy*! @move*! 2move*!" any at/to any rdo #7788
@program #2250:"@ren*ame @ren*omme 2rename @copy*! 2copy*! @move*! 2move*!" any at/to any
"Copied from Generic Player (#12):@move by Slacker (#55)Jun 30 20:52:28 1998"
"Bounce the @rename, @copy or @move request to the verb specializing in performing that opperation on objects, properties, files or verbs."
verb = {"rename", "copy", "move"}[verb[2..4] in {"ren", "cop", "mov"}] + (verb[$] == "!" ? "!" | "")
set_task_perms(player)
if (player != this)
  $msg:mtell("huh")
elseif (!iobjstr)
  player:tell(verb, " ", dobjstr, " ", prepstr, " what?")
elseif (spec = $code_utils:parse_fileref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_file")(object, spec[2], iobjstr)
  endif
elseif (spec = $code_utils:parse_propref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_prop")(object, spec[2], iobjstr)
  endif
elseif (spec = $code_utils:parse_verbref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_verb")(object, spec[2], iobjstr)
  endif
else
  object = this:my_match_object(dobjstr)
  if (!$command_utils:object_match_failed(object, dobjstr))
    this:("_" + verb + "_obj")(object, iobjstr)
  endif
endif
.