@verb #2090:".* =*" any any any rxd #562
@program #2090:".* =*" any any any
"Usage:   .join [channel]"
"         .leave [channel]"
"         .[channel] Hi"
"         .[channel] :waves."
"         .[channel] ::'s here!"
"         .[channel] -[player] Hi"
"         .[channel] -[player] :waves."
"         .[channel] -[player] ::'s here!"
"         .list  =>  returns a list of channels available to you"
"         .who  =>  returns player listening to channels with you"
""
"         Substitute the names for [channel] and [player]."
if (caller_perms().wizard || caller_perms() == player)
  if (verb == ".")
    help_message = $fossil_utils:verb_documentation(this, verb)
    player:tell(help_message)
  elseif (verb == ".join")
    if (valid(channel = this:match_channel(argstr)))
      if (channel:join(player))
      else
        player:tell("Sorry, you can't join that channel.")
      endif
    else
      player:tell("I don't know what channel you're referring to.")
    endif
  elseif (verb == ".leave")
    if (valid(channel = this:match_channel(argstr)))
      if (channel:leave(player))
        player:tell("You have left the channel.")
      elseif (typeof(ERR) == $ERR)
        player:tell("Leaving the channel failed: ", ERR)
      endif
    else
      player:tell("I don't know what channel you're referring to.")
    endif
  elseif (verb == ".list")
    x = {}
    n = ""
    for each in (children($channel))
      if (each.usable_by == 1 || player in each.usable_by)
        n = tostr(each.description) == "{list}" ? $string_utils:from_list(each.description, " ") | each.description
        x = {@x, {each:title(1), n}}
      endif
    endfor
    caller:tellColumns({15, 60}, {"Channel", "Description"}, @x)
  elseif (verb == ".who")
    for chan in (children($channel))
      if (player in chan.users)
        player:tell("** Players on channel ", chan:title(), ":")
        c = 1
        lines = {{"Player", "Idle"}}
        for x in (chan.users)
          if (x in $list_utils:append($no_one:eval("connected_players()")[2], chan.use_while_invis))
            lines = {@lines, {x.name, this:print_idle(x)}}
            c = c + 1
          endif
        endfor
        player:tellcolumns("lr", {1, 1}, @lines)
      endif
    endfor
    player:tell("** End channel .who")
  elseif (valid(channel = this:match_channel(verb[2..length(verb)])))
    this:channel_extend(channel)
    channel:parse_command(player, argstr)
  else
    player:tell("Sorry, I can't find that channel.")
  endif
endif
"Last modified by Dax (#789) on Tue May  3 13:45:59 2005 MDT."
.