@verb #17:"@tra*verse" any with/using any rdo #55
@program #17:"@tra*verse" any with/using any
if (player != this)
  $msg:mtell("huh")
  return
endif
set_task_perms(this)
tvn = "%trav"
if (dobjstr != "all")
  if ($command_utils:object_match_failed(dobj = this:my_match_object(dobjstr), dobjstr))
    return
  endif
else
  dobj = #-1
endif
if (svc = set_verb_code($wiz, tvn, {tostr("if (caller != ", this, ") return; endif"), "x = args[1];", iobjstr + ";"}))
  this:tell(svc)
  return
endif
if (valid(dobj))
  for o in ($object_utils:descendants_suspended(dobj))
    if (r = this:(tvn)(o))
      this:notify(tostr(o.name, " (", o, ") by ", o.owner, this:eval_value_to_string(r)))
    endif
    $command_utils:suspend_if_needed()
  endfor
else
  for i in [0..toint(max_object())]
    o = toobj(i)
    if (r = this:(tvn)(o))
      if (valid(o))
        this:notify(tostr(o.name, " (", o, ") by ", o.owner, this:eval_value_to_string(r)))
      else
        this:notify(tostr("Invalid (", o, ") ", this:eval_value_to_string(r)))
      endif
    endif
    $command_utils:suspend_if_needed()
  endfor
endif
this:notify("*******")
"Last modified by Dax (#789) on Tue May  3 14:14:09 2005 MDT."
.