@verb #17:"@id*entify" any none none rdo #55
@program #17:"@id*entify" any none none
if (player != this)
  return player:tell(E_PERM)
elseif ((dobj = toobj(dobjstr)) < #0 && tostr(dobj) == dobjstr)
  "Un-logged-in connection: OK"
elseif ($command_utils:player_match_failed(dobj = $string_utils:match_local_player(dobjstr), dobjstr))
  return
endif
player:notify("Attempting to trace connection (no guarantees)...")
ident = $network:ident(dobj)
if (!ident)
  player:notify(tostr("Can't identify: ", ident))
elseif (!ident[1])
  player:notify(tostr("Can't identify: ", ident[3], ": ", ident[2]))
  found = $site_db:find(ident[3])
  player:notify(tostr("Found ", length(found), " matches in the connections database for ", ident[3]))
  if (length(found) <= 5 && $command_utils:yes_or_no("View them all?"))
    for f in (found)
      player:notify(tostr(f.name, " (", f, ")"))
    endfor
  endif
else
  player:notify(tostr("Identified as ", ident[2], "@", ident[3]))
  if (found = $registration_db:find_exact(tostr(ident[2], "@", ident[3])))
    found = {found}
  else
    found = $registration_db:find_all(ident[2])
  endif
  player:notify(tostr("Found ", length(found), " matches in the player database."))
  if (length(found) <= 5 && $command_utils:yes_or_no("View them all?"))
    for f in (found)
      who = f[1][1]
      player:notify(tostr(who.email_address, ": ", who.name, " (", who, ")"))
    endfor
  endif
endif
.