@verb #16:"@give @take" any any any rdo #789
@program #16:"@give @take" any any any
"Copied from Generic Manager (#768):@give by Dax (#789) Aug 22 20:31:14 1997"
"Copied from Generic Guardian (#123):@take by Dax (#789) Aug 22 19:45:29 1997"
"Allows wizards to give and take quota."
if (player != this)
  return player:tell(E_PERM)
elseif ($command_utils:player_match_failed(victim = player:match_entity(iobjstr), iobjstr))
  return
endif
if (!this:isa($guardian) && !(victim in this.students))
  return player:tell("You don't control that player.")
endif
if (dobjstr)
  try
    amount = $quota:parse_amount(dobjstr)
  except error (E_INVARG)
    return player:tell(error[2])
  endtry
  {bytes, objects, dbytes} = amount
  if (verb == "@give")
    victim.max_vm = victim.max_vm + bytes
    victim.max_obj = victim.max_obj + objects
    victim.max_fs = victim.max_fs + dbytes
  else
    victim.max_vm = victim.max_vm - bytes
    victim.max_obj = victim.max_obj - objects
    victim.max_fs = victim.max_fs - dbytes
  endif
  player:tell("Quota transfer successful.")
else
  player:tell("Syntax:  @give [n o*bjects][n b*ytes][n k*bytes][n dk*ilobytes][n db*ytes] to <player/project>")
  player:tell("         @take [n o*bjects][n b*ytes][n k*bytes][n dk*ilobytes][n db*ytes] to <player/project>")
endif
suspend(0)
dobjstr = tostr(victim)
this:("@quota")()
"Last modified by Dax (#789) on Thu Nov  8 11:53:52 2001 MST."
.