@verb #1518:"do_www_setup" this none this rxdo #789
@program #1518:"do_www_setup" this none this
"Processes the GET arguments from a setup request."
"This verb handles outside name/description setup."
"Override to add more functionality.  Don't forget to pass."
caller == this && player:isa($webber) || raise(E_PERM)
pass(@args)
set_task_perms(player.user.wizard ? this.owner | player.user)
if ((x = $www:parse_POST("outside_name")) != E_PROPNF)
  if (x != this.outside_name)
    player:tell("<B>Changing outside name from <TT>", this.outside_name, "</TT> to <TT>", x, "</TT>.</B><BR>")
    result = `this:_set_outside_name(x) ! ANY'
    if (result == E_PERM)
      $msg:mtell("www_error", "Permission denied!  You cannot set the outside name of this room.")
    elseif (!result)
      $msg:mtell("www_error", tostr("Unknown error: ", result))
    endif
  endif
endif
if ((x = $www:parse_POST("outside_desc")) != E_PROPNF)
  if (x != this.outside_description)
    player:tell("<B>Setting the new outside description.</B><BR>")
    result = `this:_set_outside_description(x) ! ANY'
    if (result == E_PERM)
      $msg:mtell("www_error", "Permission denied!  You cannot set the outside description of this room.")
    elseif (!result)
      $msg:mtell("www_error", tostr("Unknown error: ", result))
    endif
  endif
endif
"Last modified by Dax (#789) on Thu Apr  5 15:04:24 2001 MDT."
.