@verb #14:"@rmverb" any none none rdo #55
@program #14:"@rmverb" any none none
if (player != this)
  $msg:mtell("huh")
  return
endif
set_task_perms(player)
if (!(args && (spec = $code_utils:parse_verbref(args[1]))))
  player:notify(tostr("Usage:  ", verb, " <object>:<verb>"))
elseif ($command_utils:object_match_failed(object = player:my_match_object(spec[1]), spec[1]))
  "...bogus object..."
elseif (typeof(argspec = $code_utils:parse_argspec(@listdelete(args, 1))) != $LIST)
  player:notify(tostr(argspec))
elseif (argspec[2])
  player:notify($string_utils:from_list(argspec[2], " ") + "??")
elseif (length(argspec = argspec[1]) in {1, 2})
  player:notify({"Missing preposition", "Missing iobj specification"}[length(argspec)])
else
  verbname = spec[2]
  if (index(verbname, "*") > 1)
    verbname = strsub(verbname, "*", "")
  endif
  if ((loc = $code_utils:toint(verbname)) == E_TYPE)
    loc = $code_utils:find_verb_named(object, verbname)
    if (argspec)
      argspec[2] = $code_utils:full_prep(argspec[2]) || argspec[2]
      while (loc > 0 && verb_args(object, loc) != argspec)
        loc = $code_utils:find_verb_named(object, verbname, loc + 1)
      endwhile
    endif
    if (loc < 0)
      player:notify(tostr("That object does not define that verb", argspec ? " with those args." | "."))
      return
    endif
  endif
  info = `verb_info(object, loc) ! ANY => 0'
  vargs = `verb_args(object, loc) ! ANY => 0'
  try
    result = delete_verb(object, loc)
    if (info)
      player:notify(tostr("Verb ", object, ":", info[3], " (", loc, ") {", $string_utils:from_list(vargs, " "), "} removed."))
    else
      player:notify(tostr("Unreadable verb ", object, ":", loc, " removed."))
    endif
  except (E_VERBNF)
    player:notify("That object does not define that verb.")
  except (ANY)
    player:notify(tostr(result))
  endtry
endif
"Last modified by Dax (#789) on Wed May  4 06:46:00 2005 MDT."
.