@verb #14:"@forked-v*erbose" any none none rdo #55
@program #14:"@forked-v*erbose" any none none
"Copied from Lao-Tzu (#8084):@forked by Slacker (#55)Mar 31 10:16:28 1999"
"Copied from Generic Programmer (#14):@forked by Slacker (#55)Mar 31 09:59:00 1999"
player:isa($guardian) || set_task_perms(player)
if (!dobjstr)
  tasks = queued_tasks()
elseif ($command_utils:player_match_result(dobj = $string_utils:match_player(dobjstr), dobjstr)[1])
  return
elseif ((tasks = `$wiz_utils:queued_tasks(dobj) ! E_PERM') == E_PERM)
  return player:tell(verb, " ", $string_utils:nn(dobj), ":  ", tasks)
endif
if (tasks)
  su = $string_utils
  player:tell("Queue ID    Start Time            Owner         Verb (Line) [This]")
  player:tell("--------    ----------            -----         ------------------")
  now = time()
  for task in (tasks)
    {q_id, start, x, y, owner, vloc, vname, lineno, this} = task
    if (start == $maxint)
      time = "Never"
    elseif (start == -1)
      time = "Reading input..."
    elseif (start == now)
      time = "Now"
    elseif (start < now)
      time = tostr(now - start, " seconds ago...")
    else
      time = $string_utils:from_seconds(start - now)
    endif
    time = su:left(time, 20)
    owner_name = valid(owner) ? owner.name | tostr("Dead ", owner)
    player:tell(su:left(tostr(q_id), 10), "  ", time, "  ", su:left(owner_name, 12), "  ", vloc, ":", vname, " (", lineno, ")", this != vloc ? tostr(" [", this, "]") | "")
    for x in (`task_stack(q_id, 1)[2..$] ! E_RANGE, E_INVARG => {}')
      "player:tell(toliteral(x));"
      {ts_this, ts_vname, c, ts_vloc, e, ts_line} = x
      player:tell($su:space(10), "  ", $su:space(20), "  ", $su:right("...", 12), "  ", ts_vloc, ":", ts_vname, " (", ts_line, ")", ts_vloc != ts_this ? tostr(" [", ts_this, "]") | "")
    endfor
  endfor
else
  player:tell("No tasks.")
endif
"Last modified by manta (#7165) on Wed Apr  7 13:05:14 1999 MDT."
.