@verb #14:"@args" any any any rdo #55
@program #14:"@args" any any any
if (player != caller)
  return $msg:mtell("huh")
endif
set_task_perms(player)
if (!player.programmer)
  player:_prog_disclaimer("create verbs&&creer des verbes")
  return
endif
if (!(args && (spec = $code_utils:parse_verbref(args[1]))))
  player:notify(tostr(args ? "\"" + args[1] + "\"?  " | "", "<object>:<verb>  expected."))
elseif ($command_utils:object_match_failed(object = player:my_match_object(spec[1]), spec[1]))
  "...can't find object..."
elseif (`info = verb_args(object, name = spec[2]) ! ANY' == E_VERBNF)
  player:notify("That object does not have a verb with that name.")
elseif (typeof(info) == $ERR)
  player:notify(tostr(info))
elseif (typeof(pas = $code_utils:parse_argspec(@listdelete(args, 1))) != $LIST)
  "...arg spec is bogus..."
  player:notify(tostr(pas))
elseif (!(newargs = pas[1]))
  player:notify($string_utils:from_list(info, " "))
elseif (pas[2])
  player:notify(tostr("\"", pas[2][1], "\" unexpected."))
else
  info[2] = info[2][1..index(info[2] + "/", "/") - 1]
  info = {@newargs, @info[length(newargs) + 1..length(info)]}
  try
    krusty = verb_args(object, name)
    result = set_verb_args(object, name, info)
  except (E_INVARG)
    return player:notify(tostr("\"", info[2], "\" is not a valid preposition (?)"))
  except (ANY)
    return player:notify(tostr(result))
  endtry
  player:tell("Verb arguments changed from `", $string_utils:from_list(krusty, " "), "' to `", $string_utils:from_list(verb_args(object, name), " "), ".'")
endif
"Last modified by Dax (#789) on Wed May  4 06:46:00 2005 MDT."
.