@verb #1492:"_tell_desc" this none this rxdo #60
@program #1492:"_tell_desc" this none this
who = args ? args[1] | player
plen = length(args) > 1 ? args[2] | this.length
header = length(args) > 2 && args[3]
if (this:_textp())
  text = this:text()
  len = length(text)
  if (!plen || len <= plen)
    $command_utils:suspend_if_needed()
    "6/24/93 change tell_lines to notify to reduce lag."
    if (header)
      who:tell("--------------- ", this.name, "-----")
      who:notify(text)
      who:tell("--------------- ", this.name, "-----")
    else
      who:notify(text)
    endif
    return
  endif
  offset = this:offset()
  npages = len / plen + 1
  thispage = offset / plen + 1
  if (offset != 1 || header)
    who:tell("--", thispage, " of ", npages, "----- 'prev on ", this.name, "' for previous----")
  endif
  end = offset + plen - 1
  who:tell(text[offset..min(len, end)])
  if (len > end || header)
    who:tell("--", thispage, " of ", npages, "----- 'next on ", this.name, "' for more --------")
  endif
  return
endif
this.seen = setadd(this.seen, {who, @this:_place()})
len = length(this.desclines)
if (header)
  who:tell("--------------- ", this.name, "-----")
endif
if (plen && len > plen)
  offset = this:offset()
  who:tell(this.desclines[offset..min(offset + this.length - 1, len)])
  nxt = "next on " + this.name
  prv = "previous on " + this.name
  who:tell("---- '", offset == 1 ? nxt | (offset + plen > len ? prv | "'" + nxt + "' or '" + prv + "'"), "' to see additional choices (", len, " total) ---")
else
  who:tell(this.desclines || {$string_utils:pronoun_sub("%T is empty right now.")})
  if (header)
    who:tell("--------------- ", this.name, "-----")
  endif
endif
"Last modified by Dax (#789) on Sat May 16 14:19:43 1998 EDT."
.