@verb #144:":multiply" this none this rxdo #55
@program #144:":multiply" this none this
{@bignums} = {this, @args}
decoded = {}
for x in (bignums)
  decoded = {@decoded, $list_utils:reverse(decode_binary(x.value, 1))}
endfor
result_digits = $list_utils:make(length(decoded[1]) + length(decoded[2]))
for x in [1..length(decoded[1])]
  for y in [1..length(decoded[2])]
    result_digits[x + y - 1] = result_digits[x + y - 1] + decoded[1][x] * decoded[2][y]
    $command_utils:suspend_if_needed()
  endfor
endfor
for x in [1..length(result_digits) - 1]
  result_digits[x + 1] = result_digits[x + 1] + result_digits[x] / 256
  result_digits[x] = result_digits[x] % 256
  $command_utils:suspend_if_needed()
endfor
while (result_digits && result_digits[$] == 0)
  result_digits[$..$] = {}
endwhile
this.value = encode_binary($list_utils:reverse(result_digits))
"Last modified by manta (#7165) on Tue Mar  6 21:34:23 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:06 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:06 2002 MDT."
.