@verb #1409:"tell_www_body" this none this rxdo #8084
@program #1409:"tell_www_body" this none this
pass(@args)
if (listassoc("isindex", dobj) == {"isindex", "all"})
  data = {}
  for x in (this.quotes)
    data = {@data, {tostr(x[3], " (", x[1], ")"), $su:currency(this:_get_value(x[1])), tostr("<a href=\"http://www.moo.ca/smfo?symbol=", x[1], "\"><img border=0 src=\"http://files.moo.ca/1/4/0/9/", $su:lowercase(x[1]), "-small.gif\"></a>")}}
  endfor
  data = $list_utils:sort(data, $list_utils:slice(data, 1))
  player:tellColumnsEx(2, "lll", {1, 1, 1}, {"Company", "Current Price", "Graph"}, @data)
  return
endif
if (listassoc("isindex", dobj) == {"isindex", "compare"})
  player:tell("<form method=\"post\" action=\"/smfo\">")
  player:tell("<input type=\"hidden\" name=\"type\" value=\"compare\">")
  player:tell("<p>Select up to five stocks to compare:</p>")
  for x in [1..5]
    player:tell("<select name=\"stock", x, "\" size=\"10\">")
    player:tell("<option value=\"_none\" selected=\"yes\"></option>")
    for z in ($list_utils:sort(this.quotes, $list_utils:slice(this.quotes, 3)))
      player:tell("<option value=\"", z[1], "\">", z[3], " (", z[1], ")</option>")
    endfor
    player:tell("</select>")
  endfor
  player:tell("<input type=\"submit\" value=\"Compare!\">")
  player:tell("</form>")
  return
endif
if (!listassoc("symbol", dobj) && (index = player.user in this.users))
  ui = this.user_info[index]
  data = {}
  for x in (ui[2])
    data = {@data, {tostr(listassoc(x[1], this.quotes)[3], " (", x[1], ")"), $su:group_number(x[2]), $su:currency(this:_get_value(x[1])), $su:currency(x[3]), $su:currency(this:_get_value(x[1]) * tofloat(x[2])), this:_link_w_plot(x[1])}}
  endfor
  player:tellColumns("llllll", $list_utils:make(6, 1), {"Company", "Shares", "Current Price", "Invested", "Current Value", "Graph"}, @data)
endif
if (listassoc("type", dobj) == {"type", "activex"} || listassoc("type", iobj) == {"type", "compare"})
  player:tell(this:fileread("plfplotocx.html"))
  return
endif
z = listassoc("symbol", dobj)
player:tell("<form method=\"GET\" action=\"/smfo\">")
player:tell("Stock symbol: ")
player:tell("<select name=\"symbol\">")
for x in ($list_utils:sort(this.quotes, $list_utils:slice(this.quotes, 1)))
  player:tell("<option value=\"", x[1], "\"", z && z[2] == x[1] ? " selected" | "", ">", x[3], " (", x[1], ")")
endfor
player:tell("</select> <input type=\"submit\" value=\"View Graph\"></form>")
if (z)
  symbol = z[2]
  player:tell("<img width=640 height=480 src=\"http://files.moo.ca/1/4/0/9/", $su:lowercase(symbol), ".gif\">")
elseif (!(player.user in this.users))
  player:tell("<img width=640 height=480 src=\"http://files.moo.ca/1/4/0/9/smfo.gif\">")
endif
"Last modified by Lao-Tzu (#8084) on Thu Jun 28 08:55:50 2001 MDT."
.