@verb #13:"@mess*ages" any none none rdo #55
@program #13:"@mess*ages" any none none
"Copied from Generic Player (#12):@mess by Slacker (#55) Nov  6 13:59:25 2002"
set_task_perms(player)
if ($command_utils:object_match_failed(dobj, dobjstr))
  return
endif
found_one = 0
props = $object_utils:all_properties(dobj)
if (typeof(props) == $ERR)
  player:tell("You can't read the messages on that.")
  return
endif
for pname in (props)
  len = length(pname)
  if (len > 4 && pname[1..4] == "msg_")
    found_one = 1
    try
      msg = dobj.(pname)
      mname = pname[5..$]
    except (E_PERM)
      player:sub_tell("@%1 #%d~# is ...unreadable...", mname)
      continue
    endtry
    if (!msg)
      player:sub_tell("@%1 #%d~# is ...not set...", mname)
    else
      player:tell("@", mname, " ", tostr(dobj), " is ", toliteral($html_utils:literal_text(msg)))
    endif
  endif
  $command_utils:suspend_if_needed()
endfor
if (!found_one)
  player:tell("That object has no messages.")
endif
"Last modified by Dax (#789) on Tue May  3 13:45:56 2005 MDT."
.