@verb #13:"@create" any any any rdo #55
@program #13:"@create" any any any
set_task_perms(player)
nargs = length(args)
pos = "named" in args
if (pos <= 1 || pos == nargs)
  pos = "called" in args
endif
if (pos <= 1 || pos == nargs)
  player:tell("Usage: @create &lt;parent-class&gt; named name,alias,alias...")
  player:tell("where &lt;parent-class&gt; is one of the standard classes ($thing, $note...) or an object number (e.g. #123), or the name of an object in the current room.  You can use 'called' instead of 'named'.")
  return
endif
parentstr = $string_utils:from_list(args[1..pos - 1], " ")
namestr = $string_utils:from_list(args[pos + 1..nargs], " ")
parent = player:my_match_object(parentstr)
if ($command_utils:object_match_failed(parent, parentstr))
  return
endif
object = $recycler:create(parent)
if (typeof(object) == $ERR)
  return player:tell(object)
endif
x = 0
while (object.owner == $nothing)
  suspend(0)
  x = x + 1
  if (x == 5)
    return player:tell("Unable to @create object.  Try again.  If that fails, talk to a wizard.")
  endif
endwhile
$building_utils:set_names(object, namestr)
if (object:isa($player))
  move(object, player.location)
elseif (object:isa($room))
  move(object, $czone)
elseif (object:isa($physical))
  move(object, player)
endif
other_names = setremove(object.aliases, object.name)
if (!other_names)
  $msg:mtell("created", object, parent)
else
  $msg:mtell("created_aka", object, parent, other_names)
endif
"Last modified by Dax (#789) on Tue May  3 13:45:55 2005 MDT."
.