@verb #13:"@chown @transfer" any any any rdo #55
@program #13:"@chown @transfer" any any any
"Copied from Generic Wizard (#58):@chown by Dead_Duck (#396) Aug 19 03:26:54 1996"
"Copied from Generic Teacher (#768):@chown by Juggler (#396) Jan 11 23:06:12 1996"
if ($command_utils:player_match_failed(iobj = $string_utils:match_player(iobjstr), iobjstr))
  return
elseif (!$perm_utils:controls(player, iobj) && !$perm_utils:controls(player, iobj.owner))
  return $msg:mtell("not_own", iobj)
elseif (`is_player(dobj) || dobj:isa($player) ! E_INVIND, E_INVARG => 0')
  return player:tell("Uhh, no chowning of players. They should only be owned by themselves.")
elseif (index(dobjstr, ".") && (spec = $code_utils:parse_propref(dobjstr)))
  if ($command_utils:object_match_failed(object = player:my_match_object(spec[1]), spec[1]))
    return
  elseif (!(pi = `property_info(object, prop = spec[2]) ! ANY'))
    return player:tell(pi)
  elseif (!player:controls_property(object, prop))
    return $msg:mtell("not_own", dobjstr)
  endif
  e = $wiz_utils:set_property_owner(object, prop, iobj)
  if (e == E_NONE)
    player:tell("+c property owner changed -- did you really want to do that?")
  elseif (e != 0 && e != 1)
    player:tell(e)
  else
    $msg:mtell("chowned", dobjstr, pi[1], iobj)
  endif
elseif (index(dobjstr, ":") && (spec = $code_utils:parse_verbref(dobjstr)))
  if ($command_utils:object_match_failed(object = player:my_match_object(spec[1]), spec[1]))
    return
  elseif (!(vi = `verb_info(object, verb = spec[2]) ! ANY'))
    return player:tell(vi)
  endif
  oldowner = vi[1]
  if (!player:controls_verb(object, verb))
    return $msg:mtell("not_own", dobjstr)
  endif
  vi[1] = iobj
  if (typeof(e = set_verb_info(object, verb, vi)) == $ERR)
    player:tell(e)
  else
    $msg:mtell("chowned", dobjstr, oldowner, iobj)
  endif
else
  if ($command_utils:object_match_failed(object = player:my_match_object(dobjstr), dobjstr))
    return
  endif
  oldowner = object.owner
  if (!$perm_utils:controls(player, oldowner) && !$perm_utils:controls(player, oldowner.owner))
    $msg:mtell("not_own", object)
  elseif (!player.wizard && player == object)
    player:tell(E_RECMOVE)
  elseif (!(e = $wiz_utils:set_owner(object, iobj, "suspend")))
    player:tell(e)
  else
    $msg:mtell("chowned", object, oldowner, iobj)
  endif
endif
"Last modified by Dax (#789) on Tue May  3 13:45:55 2005 MDT."
.