@verb #1314:"tell_www_body" this none this rxdo #1314
@program #1314:"tell_www_body" this none this
player:sub_tell("<H1>%T</H1>")
player:tell("Welcome to another session with your computer psychiatrist, Eliza.<BR>Nothing you say here is logged.  Eliza doesn't gossip.")
player:tell("<FORM NAME='f' METHOD='post' ACTION='/eliza'>")
log = {}
for x in [1..this.web_history]
  line = $www:parse_POST(tostr("log", x))
  if (line)
    log = {@log, line}
  endif
endfor
response = ""
line = $www:parse_POST("q")
if (line)
  last = line ? line[$] | ""
  log = {@log, tostr("You ", last == "?" ? "ask" | (last == "!" ? "exclaim" | "say"), ", \"", line, "\"")}
  response = this:jabber(line)
elseif (!log)
  response = this:intro()
endif
if (!response)
elseif (response[1] == "\"")
  last = response ? response[$] | ""
  log = {@log, tostr(this:title(), " ", last == "?" ? "asks" | (last == "!" ? "exclaims" | "says"), ", \"", response[2..$], "\"")}
elseif (response[1] == ":")
  log = {@log, tostr(this:title(), " ", response[2..$])}
else
  raise(E_PERM)
endif
log = log[max(1, $ - this.web_history + 1)..$]
player:tell("<BLOCKQUOTE><TT>")
for x in [1..length(log)]
  player:tell($html_utils:input_hidden(tostr("log", x), log[x]))
  if (x == length(log))
    "Add a little delay to make her look a bit more human."
    suspend(this.delay)
  endif
  player:tell($html_utils:literal_text(log[x]), "<BR>")
endfor
player:tell("</TT><P>")
player:tell("<INPUT TYPE='text' NAME='q' SIZE=40>")
player:tell("<INPUT TYPE='submit' VALUE='Ask'>")
player:tell("</BLOCKQUOTE>")
player:tell("</FORM>")
"Last modified by Dax (#789) on Sat Nov  2 21:15:19 2002 MST."
.