@verb #12:"set_name _set_name" this none this rxdo #55
@program #12:"set_name _set_name" this none this
"set_name(newname) attempts to change this.name to newname"
"  => E_PERM   if you don't own this"
"  => E_INVARG if the name is already taken or prohibited for some reason"
"  => E_NACC   if the player database is not taking new names right now."
"  => E_ARGS   if the name is too long (controlled by $login.max_player_name)"
if (!$perm_utils:controls(caller_perms(), this) && !(this == caller))
  raise(E_PERM)
elseif (!is_player(this))
  "we don't worry about the names of player classes."
  set_task_perms(caller_perms())
  return pass(@args)
elseif ($player_db.frozen)
  raise(E_NACC)
endif
name = args[1]
if ($html_utils:detag(name) != name)
  raise(E_INVARG)
endif
if (length(name) > $login.max_player_name)
  raise(E_ARGS)
endif
if (!($player_db:available(name) in {this, 1}))
  raise(E_INVARG)
else
  old = this.name
  pass(@args)
  if (name != old && !(old in this.aliases))
    $player_db:delete(old)
  endif
  $player_db:insert(name, this)
  return 1
endif
"Last modified by Dax (#789) on Sun Jul 28 13:07:42 2002 MDT."
.