@verb #12:"parse_folder_spec" this none this rxdo #55
@program #12:"parse_folder_spec" this none this
":parse_folder_spec(verb,args,expected_preposition[,allow_trailing_args_p])"
" => {folder, msg_seq_args, trailing_args}"
set_task_perms(caller_perms())
folder = this:current_folder()
if (!prepstr)
  return {folder, args[2], {}}
endif
{verb, args, prep, ?extra = 0} = args
p = prepstr in args
if (prepstr != prep)
  "...unexpected preposition..."
  if (extra && !index(prepstr, " "))
    return {folder, args[1..p - 1], args[p..length(args)]}
  else
    player:tell("Usage:  ", verb, " [<message numbers>] [", prep, " <folder/list-name>]")
  endif
elseif (!(p < length(args) && (fname = args[p + 1])))
  "...preposition but no iobj..."
  player:tell(verb, " ", $string_utils:from_list(args, " "), " WHAT?")
elseif ($mail_agent:match_failed(folder = typeof(m = $mail_agent:match_recipient(fname)) == $LIST ? m[1] | m, fname))
  "...bogus mail folder..."
else
  return {folder, args[1..p - 1], args[p + 2..length(args)]}
endif
return 0
"Last modified by Dax (#789) on Tue May  3 13:55:52 2005 MDT."
.