@verb #12:"my_match" this none this rxdo #55
@program #12:"my_match" this none this
"Decides, from the point-of-view of `who', which of the following `visible' objects `string' matches"
{string, objects, ?who = this} = args
all = 0
if (parsed = $match_utils:parse_all_reference(string))
  string = parsed
  all = 1
endif
objects = $list_utils:remove_duplicates(objects)
m = {}
if (string in $msg.me)
  m = {who}
elseif (string in $msg.here)
  m = {who.location}
elseif (matches = $match_utils:match_absolute(string))
  m = matches
elseif (matches = $match_utils:match_all(string, objects))
  m = matches
elseif ((parsed = $match_utils:parse_ordinal_reference(string)) && (matches = {$match_utils:match_nth(parsed[2], objects, parsed[1])}))
  m = matches
elseif (parsed = $match_utils:parse_possessive_reference(string))
  {whostr, objstr} = parsed
  if (valid(who = this:my_match(whostr, objects, this)))
    return who:match(objstr, this)
  endif
endif
if (m == {})
  return $failed_match
elseif (all)
  return m
elseif (length(m) > 1)
  return $ambiguous_match
else
  return m[1]
endif
"Last modified by manta (#7165) on Mon Nov 12 10:55:13 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.