@verb #12:"dis*s boo praise worship" this for/about any rd #55
@program #12:"dis*s boo praise worship" this for/about any
"dis*s <player>"
"Disrespects this player."
"A dis is more serious than a boo; a worship higher than a praise."
if (verb == "diss")
  verb = "dis"
endif
for x in ({player, this})
  $esteem_utils:check_for_tampering(x)
endfor
if (player.location != this.location && this.location:acceptable(player))
  "So you have to be in the same room, unless target has locked you out."
  player:_modify_esteem(-0.1)
  return $msg:mtell(verb + "_not_here")
endif
if (player == this)
  this:_modify_esteem(-20.0)
  return $msg:mtell(verb + "_self", iobjstr)
endif
weights = $esteem_utils.(verb + "_weights")
if ($esteem_utils:("can_" + verb)(player, this))
  this:_modify_esteem(weights[1])
  player:_modify_esteem(weights[2])
  $esteem_utils:update_for_action(player, this, verb)
  return $msg:mtell({this, "i"}, verb, iobjstr)
else
  player:_modify_esteem(-0.5)
  return $msg:mtell({this, "i"}, verb + "_failed", iobjstr)
endif
"Last modified by whiz (#3135) on Thu Apr 25 00:24:28 2002 MDT."
"This verb previously owned by whiz (#3135), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:02 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:02 2002 MDT."
.